*  JieJie Microelectronics P-Spice Model Library
*  Filename	: JMSH1507AC_P v.20210910.txt
*  Product Name      	: JMSH1507AC (TO-220-3L)
*  Configuration:	: Single N-channel Device
*  Data Sheet Rev.	: 1.2
*  Release Date	: Sep 10, 2021
*  Junction Temp (Tj)	: -40C ~ 150C
******************************************************************************************************
*  This model is designed as a tool to assist end user(s) to evaluate the performance
*  of the particular SGT MOSFET (named above) released by JJMSH(R).  It has been
*  verified for function and timing integrity with the commercially available EDA simulat-
*  ion tools. End-user(s) is/are advised to take the best engineering practice (e.g.
*  bread-boarding, laboratory measurement) for the full evaluation.
*
*  Despite of the best effort on engineering & verification, JieJie Microelectronics Co.,
*  Ltd. ("JJM") does not provide any warranty nor take any liability to the results and
*  their effects whatsoever from the simulation run of this model by the end-user(s).
*  While this model may be updated at appropriate times in the future without prior
*  notice, JJM does not assume the sole responsibility for update. 
*
.subckt JMSH1507AC D G S 
M1 1 2 3 3 NMOS L=1E-006 W=1E-006

Vmonitor D 18 0

RD 18 1 0.0025
RS S 3 1E-006
RG G 17 2.05
CGS 3 G 4.3E-9
EGD 12 0 2 1 1

Etemp 17 2 VALUE = {(-0.00489*(TEMP-25))+((-7.21205E-6)*(TEMP-25)^2)}
Gtemp 1 3 VALUE = {I(Vmonitor)*((TEMP+273)/(298)-((TEMP+273)/(298))^1.65)}

VFB 14 0 0
FFB 2 1 VFB 1
CGD 13 14 5E-10
DDG 15 14 DCGD
R2 12 15 1
D2 15 0 DLIM
DSD 3 D DSUB
RR 13 0 1
D1 12 13 DLIM

Cbreak D 3 Cbreak 4.73515E-9
.MODEL Cbreak CAP (C = 1 VC1 = -0.01854 VC2 = 8.71301E-5)

.model NMOS NMOS
+LEVEL = 3                                      
+VMAX = 1.0752E9               ETA = 1E-4                    
+VTO = 3                       TOX = 8E-10                   NSUB = 3.55E15                
+KP = 150                      U0 = 424                      KAPPA = 0.1                   
+GAMMA = -2.320005             PHI = 0.6                     THETA = 0.2                   
+DELTA = 300                   

.model DCGD D
+CJO = 1E-9                    VJ = 50                       M = 3.97                      

.model DSUB D
+IS = 8E-10                    N = 1.255                     RS = 1E-3                     
+BV = 159                      xti = 4                       
       

.model DLIM D
+IS = 1E-4                     
.ends JMSH1507AC

******************************************************************************************************
*  Copyright (C) 2021 JJM. All rights reserved.
******************************************************************************************************
